Project:SPARQL/examples

From Weinetiketten der Mosel

Überblick | Overview

Weinetiketten kartiert nach Gemeinde | Wine labels mapped by village

 

#defaultView:Map
# Weinetiketten, die mit einem Ort verknüpft sind und dadurch geolokalisiert werden können. 
# Aktuell nicht implementiert: Geolokalisierung über Lage oder Weingut. Daher fehlt hier der Riesling von Julian Haart. 
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT 
  ?CID
  ?EtikettentypLabel
  ?Weinbezeichnung 
  ?OrtLabel 
  (STR(?yearA) AS ?Jahrgang)
  (STR(?DatierungB) AS ?Datierung)
  ?Geolocation 
  ?BildCommons 
  ?BildURL
  ?Etikett 
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  OPTIONAL { ?Etikett wdt:P39 ?CID . }
  ?Etikett wdt:P5 ?Etikettentyp . 
  ?Etikett wdt:P31 ?Ort . 
  OPTIONAL { ?Etikett wdt:P30 ?Weinbezeichnung . }
  OPTIONAL { 
    ?Etikett wdt:P40 ?year . 
    BIND(YEAR(?year) AS ?yearA)
   FILTER(BOUND(?yearA)) } 
  OPTIONAL { 
    ?Etikett wdt:P78 ?DatierungA . 
    BIND(YEAR(?DatierungA) AS ?DatierungB)
   FILTER(BOUND(?yearA)) } 
  OPTIONAL { ?Ort wdt:P27 ?Geolocation . }
  OPTIONAL { ?Etikett wdt:P4 ?BildCommons . }
  OPTIONAL { ?Etikett wdt:P29 ?BildURL . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
ORDER BY ASC(?Jahrgang)

Try it!


Alle Lagen nach Ort kartiert | All vineyards mapped by village

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?EinzellageLabel ?LeitgemeindeLabel ?Geolocation ?Einzellage
WHERE {
  ?Einzellage wdt:P5 wd:Q11 .
  ?Einzellage wdt:P24 wd:Q29 .
  ?Einzellage wdt:P14 ?Leitgemeinde .
  OPTIONAL { ?Leitgemeinde wdt:P27 ?Geolocation . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Etiketten mit Scan in der Übersicht | Labels with scan as an overview

# Alle Weinetiketten mit Scan
#defaultView:ImageGrid
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?EtikettLabel
  ?OrtName
  ?Bild
  ?Etikett
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  #?Etikett wdt:P31 wd:Q239 . # Q101=Bernkastel  Q103=Brauneberg Q239=Wiltingen
  ?Etikett wdt:P31 ?Ort . 
  ?Ort rdfs:label ?OrtName .
  FILTER(LANG(?OrtName) = "de")
  ?Etikett wdt:P4 ?Bild 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }}
ORDER BY ASC(?OrtLabel)

Try it!


Lagen | Vineyards

Lagen nach Gemarkung (noch unvollständig kodiert) | Vineyards by cadastral area (incomplete)

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?EinzellageLabel ?LeitgemeindeLabel ?Geolocation ?Einzellage
WHERE {
  ?Einzellage wdt:P5 wd:Q11 .
  ?Einzellage wdt:P14 ?Leitgemeinde .
  OPTIONAL { ?Leitgemeinde wdt:P27 ?Geolocation . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Alle Altlagen nach Gemeinde kartiert | All historical vineyards mapped by village

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?EinzellageLabel ?LeitgemeindeLabel ?Geolocation ?Einzellage
WHERE {
  ?Einzellage wdt:P24 wd:Q28 .
  ?Einzellage wdt:P14 ?Leitgemeinde .
  OPTIONAL { ?Leitgemeinde wdt:P27 ?Geolocation . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Alle aktuellen Lagen nach Gemeinde kartiert | All current vineyards mapped by village

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?EinzellageLabel ?LeitgemeindeLabel ?Geolocation ?Einzellage
WHERE {
  ?Einzellage wdt:P5 wd:Q11 .
  ?Einzellage wdt:P24 wd:Q29 .
  ?Einzellage wdt:P14 ?Leitgemeinde .
  OPTIONAL { ?Leitgemeinde wdt:P27 ?Geolocation . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Die (bisher sehr wenigen) Einzellagen mit eigener, genauerer Geolocation auf einer Karte | The (currently very few) individual vineyards mapped according to their own, precise geolocation

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?lage ?lageLabel ?location
WHERE {
  ?lage wdt:P5 wd:Q11.
  ?lage wdt:P27 ?location. 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Alle Einzellagen mit einigen Infos | All individual vineyards with some information

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?Lage ?TypLabel ?LeitgemeindeLabel ?LageLabel ?GroßlageLabel ?GemarkungLabel ?Rebfläche ?ExpositionLabel ?DWI ?LWK
WHERE {
  ?Lage wdt:P5 wd:Q11 .
  OPTIONAL { ?Lage wdt:P9 ?Großlage . }
  OPTIONAL { ?Lage wdt:P24 ?Typ . }
  OPTIONAL { ?Lage wdt:P14 ?Leitgemeinde . }
  OPTIONAL { ?Lage wdt:P18 ?Gemarkung . }
  OPTIONAL { ?Lage wdt:P20 ?Rebfläche . }
  OPTIONAL { ?Lage wdt:P21 ?Exposition . }
  OPTIONAL { ?Lage wdt:P17 ?DWI . }
  OPTIONAL { ?Lage wdt:P52 ?LWK . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Lagen mit einer bestimmten Kombination von Exposition und Bodentyp (als Beispiel) | A vineyard with a specific combination of exposition and soil type (as an example)

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?EinzellageLabel ?LeitgemeindeLabel ?BodentypLabel ?ExpositionLabel ?Geolocation ?Einzellage
WHERE {
  ?Einzellage wdt:P5 wd:Q11 .
  ?Einzellage wdt:P24 wd:Q29 .
  ?Einzellage wdt:P14 ?Leitgemeinde .
  #?Einzellage wdt:P21 ?Exposition . 
  #?Einzellage wdt:P68 ?Bodentyp . 
  ?Einzellage wdt:P21 wd:Q252.        # Bestimmte Exposition: siehe: https://mosel.wikibase.cloud/wiki/Special:WhatLinksHere/Item:Q1847
  ?Einzellage wdt:P68 wd:Q1857 .      # Bestimmter Bodentyp: siehe hier: https://mosel.wikibase.cloud/wiki/Special:WhatLinksHere/Item:Q30 
  OPTIONAL { ?Leitgemeinde wdt:P27 ?Geolocation . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!


Die Bodentypen | The soil types

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?BodentypLabel ?Bodentyp
WHERE {
  ?Bodentyp wdt:P5 wd:Q1847 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!


Alle aktuellen Lagen in einem bestimmten Bereich | All current vineyards in a specific area

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?BereichLabel ?EinzellageLabel ?LeitgemeindeLabel ?Geolocation ?Einzellage
WHERE {
  ?Einzellage wdt:P5 wd:Q11 .
  ?Einzellage wdt:P9 ?Grosslage . 
  ?Grosslage wdt:P10 wd:Q16 .         # Bestimmter Bereich: Q16=Bernkastel (Bereich) 
  ?Einzellage wdt:P24 wd:Q29 .         # Lagentyp: Q29=Aktuelle-Lage, Q28=Altlage;  
  OPTIONAL { ?Einzellage wdt:P14 ?Leitgemeinde . }
  OPTIONAL { ?Leitgemeinde wdt:P27 ?Geolocation . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!


Weinetiketten | Wine labels

Etiketten mit Basisinfos | Wine labels with basic metadata

# Alle Weinetiketten
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?EtikettLabel
  ?ClassLabel
  ?TypeLabel
  ?Weinbezeichnung 
  (GROUP_CONCAT(DISTINCT ?OrtName; separator=", ") AS ?Orte) 
  ?Jahr 
  #?Datierung
  ?CollectionID
  ?Etikett 
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  OPTIONAL { ?Etikett wdt:P30 ?Weinbezeichnung . }
  OPTIONAL { ?Etikett wdt:P5 ?Class . }
  OPTIONAL { ?Etikett wdt:P55 ?Type . }
  OPTIONAL {
    ?Etikett wdt:P31 ?Ort . 
    ?Ort rdfs:label ?OrtName .
    FILTER(LANG(?OrtName) = "de")
    }
  OPTIONAL {
    ?Etikett wdt:P40 ?PIT . 
    BIND(YEAR(?PIT) AS ?Jahr) 
    }
  OPTIONAL { ?Etikett wdt:P39 ?CollectionID . }
  OPTIONAL { ?Etikett wdt:P78 ?Datierung . } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
GROUP BY ?EtikettLabel ?ClassLabel ?TypeLabel ?Jahr ?CollectionID ?Etikett ?Weinbezeichnung
ORDER BY ASC(?CollectionID)

Try it!


Alle Etiketten mit einigen Basisinfos | All labels with some basic information

# Alle Weinetiketten
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?EtikettLabel
  ?ClassLabel
  ?TypeLabel
  ?Weinbezeichnung 
  (GROUP_CONCAT(DISTINCT ?OrtName; separator=", ") AS ?Orte) 
  ?Jahr 
  #?Datierung
  ?CollectionID
  ?Etikett 
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  OPTIONAL { ?Etikett wdt:P30 ?Weinbezeichnung . }
  OPTIONAL { ?Etikett wdt:P5 ?Class . }
  OPTIONAL { ?Etikett wdt:P55 ?Type . }
  OPTIONAL {
    ?Etikett wdt:P31 ?Ort . 
    ?Ort rdfs:label ?OrtName .
    FILTER(LANG(?OrtName) = "de")
    }
  OPTIONAL {
    ?Etikett wdt:P40 ?PIT . 
    BIND(YEAR(?PIT) AS ?Jahr) 
    }
  OPTIONAL { ?Etikett wdt:P39 ?CollectionID . }
  OPTIONAL { ?Etikett wdt:P78 ?Datierung . } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
GROUP BY ?EtikettLabel ?ClassLabel ?TypeLabel ?Jahr ?CollectionID ?Etikett ?Weinbezeichnung
ORDER BY ASC(?CollectionID)

Try it!


Alle Etiketten | All labels

# Alle Weinetiketten

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?EtikettLabel
  ?OrtLabel
  ?Etikett 
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  OPTIONAL {?Etikett wdt:P31 ?Ort . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!


Alle Etiketten mit ihren Bildmotiven | All labels with their depicted objects

# Weinetiketten mit bestimmtem Bildmotiv

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT
  ?EtikettentypLabel 
  ?Weinbezeichnung 
  ?OrtLabel 
  (STR(?yearA) AS ?Jahrgang)
  (GROUP_CONCAT(DISTINCT ?BildobjektName; separator=", ") AS ?Bildobjekte) 
  #?BildCommons 
  #?BildURL
  ?Eintrag
WHERE {
  ?Eintrag wdt:P5/wdt:P6* wd:Q43 .
  #?Eintrag wdt:P42 wd:Q879 . # Zeigt Bildobjekt: Q879 = Weinblätter; Q896 = Vogel
  ?Eintrag wdt:P5 ?Etikettentyp . 
  ?Eintrag wdt:P31 ?Ort . 
  ?Eintrag wdt:P42 ?Bildobjekt . 
  ?Bildobjekt rdfs:label ?BildobjektName . 
  FILTER(LANG(?BildobjektName) = "de")
  OPTIONAL { ?Eintrag wdt:P30 ?Weinbezeichnung . }
  OPTIONAL { ?Eintrag wdt:P4 ?BildCommons . }
  OPTIONAL { ?Eintrag wdt:P29 ?BildURL . }
  OPTIONAL {
    ?Eintrag wdt:P40 ?JahrgangA .
    BIND(YEAR(?JahrgangA) AS ?yearA)
    FILTER(BOUND(?yearA)) 
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  }
GROUP BY
  ?EtikettentypLabel 
  ?Weinbezeichnung 
  ?OrtLabel 
  ?BildCommons 
  ?BildURL
  ?Eintrag
  ?yearA
ORDER BY ASC(?Jahrgang)

Try it!


Alle Etiketten mit einem bestimmtem Bildmotiv, bspw. Weinblatt (anpassbar) | Labels with a particular depicted object, e.g. vine leaf

# Weinetiketten mit bestimmtem Bildmotiv
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT 
  ?EtikettentypLabel 
  ?Weinbezeichnung 
  ?OrtLabel 
  ?BildCommons 
  ?BildURL
  ?Eintrag
WHERE {
  ?Eintrag wdt:P5/wdt:P6* wd:Q43 .
  ?Eintrag wdt:P42 wd:Q879 . # Zeigt Bildobjekt: Q879 = Weinblätter; Q896 = Vogel
  ?Eintrag wdt:P5 ?Etikettentyp . 
  ?Eintrag wdt:P31 ?Ort . 
  OPTIONAL { ?Eintrag wdt:P30 ?Weinbezeichnung . }
  OPTIONAL { ?Eintrag wdt:P4 ?BildCommons . }
  OPTIONAL { ?Eintrag wdt:P29 ?BildURL . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!


=== Alle Bildmotive | All depicted objects 

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?KategorieLabel  # Name of the associated category
  ?BildmotivLabel  # Name of the depicted object
  ?Wikidata_ID      # Optional Wikidata ID if available
  ?ICONCLASS_ID
  ?GettyAAT_ID
  ?Bildmotiv       # The entity ID for the depicted object
WHERE {
  ?Bildmotiv wdt:P5/wdt:P6* wd:Q864 .   # Filter for depicted objects (Q864)
  ?Bildmotiv wdt:P41 ?Kategorie .       # Get the category for each depicted object
  OPTIONAL { ?Bildmotiv wdt:P12 ?Wikidata_ID . }  # Optional WikidataID
  OPTIONAL { ?Bildmotiv wdt:P86 ?ICONCLASS_ID . }  # Optional WikidataID
  OPTIONAL { ?Bildmotiv wdt:P88 ?GettyAAT_ID . }  # Optional WikidataID
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }  # Get labels in German
  }
ORDER BY ASC(?KategorieLabel) ASC(?BildmotivLabel)  # First by category, then by label

Try it!


Anzahl Etiketten pro Jahrzehnt und Etikettentyp | Number of labels per type of label and decade

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT
  ?Decade  # Using the pre-bound Decade
  ?EtikettentypLabel
  (COUNT(?Eintrag) AS ?NumberOfLabels)
WHERE {
  ?Eintrag wdt:P5/wdt:P6* wd:Q43 .
  ?Eintrag wdt:P5 ?Etikettentyp . 
OPTIONAL {
    ?Eintrag wdt:P40 ?JahrgangA .
    BIND(YEAR(?JahrgangA) AS ?yearA)
    BIND(FLOOR(?yearA / 10) * 10 AS ?Decade)  # Bind the Decade separately
    FILTER(BOUND(?yearA))
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
GROUP BY ?Decade ?EtikettentypLabel
HAVING(BOUND(?Decade))  # Make sure only entries with a year are included
ORDER BY ?Decade ?EtikettentypLabel

Try it!


Anzahl der Etiketten pro Ort (ohne "unbekannt") | Number of labels per village (without "unknown")

# Count occurrences of each "Ort"
#defaultView:BubbleChart
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT
  ?OrtLabel 
  (COUNT(?item) AS ?count)
WHERE {
  ?item wdt:P5/wdt:P6* wd:Q43 .
  ?item wdt:P31 ?Ort . 
  FILTER (?Ort != wd:Q2715)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
GROUP BY ?OrtLabel
ORDER BY DESC(?count)
LIMIT 25

Try it!


Anzahl der Etiketten pro Lage (ohne "unbekannt") | Number of labels per vineyard (without "unknown")

# Count occurrences of each "Ort"
#defaultView:BubbleChart
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT
  ?LageLabel 
  (COUNT(?item) AS ?count)
WHERE {
  ?item wdt:P5/wdt:P6* wd:Q43 .
  ?item wdt:P32 ?Lage . 
  FILTER (?Lage != wd:Q2716)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
GROUP BY ?LageLabel
ORDER BY DESC(?count)
LIMIT 25

Try it!


Anzahl der Etiketten pro Jahr (ohne "9999" / fehlende Angabe) | Number of labels per year (without undated labels)

# Count occurrences of each "Ort"
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT
  ?Jahr 
  (COUNT(?item) AS ?count)
WHERE {
  ?item wdt:P5/wdt:P6* wd:Q43 .
  ?item wdt:P40 ?PIT . 
  BIND(YEAR(?PIT) AS ?Jahr) 
  FILTER (!CONTAINS(STR(?Jahr), "9999"))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
GROUP BY ?Jahr
ORDER BY ASC(?Jahr)
LIMIT 200

Try it!


Häufigkeit der Bildmotive | Frequency of depicted objects

# Häufigkeit der Bildmotive 
#defaultView:BubbleChart
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT
  ?bildLabel
  (COUNT(?bild) AS ?count)
WHERE {
  ?Eintrag wdt:P5/wdt:P6* wd:Q43 .
  ?Eintrag wdt:P42 ?bild . 
  ?bild rdfs:label ?bildLabel .  
  FILTER(LANG(?bildLabel) = "de")  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  }
GROUP BY ?bildLabel
LIMIT 50

Try it!


Etiketten für einen bestimmten Ort als ImageGrid | Labels from one particular village as an ImageGrid

# Alle Weinetiketten
#defaultView:ImageGrid
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?EtikettLabel
  #?Weinbezeichnung 
  ?Ort
  #?CollectionID
  ?Bild
  ?Etikett
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  ?Etikett wdt:P31 wd:Q101 . # Q101=Bernkastel  Q103=Brauneberg 
  ?Etikett wdt:P31 ?Ort . 
  ?Ort rdfs:label ?OrtName .
  FILTER(LANG(?OrtName) = "de")
  ?Etikett wdt:P4 ?Bild 
  #OPTIONAL { ?Etikett wdt:P30 ?Weinbezeichnung . }
  #OPTIONAL { ?Etikett wdt:P39 ?CollectionID . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
ORDER BY ASC(?CollectionID)

Try it!


Etiketten mit Scan in der Übersicht | Labels with scan as an overview

# Alle Weinetiketten mit Scan
#defaultView:ImageGrid
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT DISTINCT 
  ?EtikettLabel
  ?OrtName
  ?Bild
  ?Etikett
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 .
  #?Etikett wdt:P31 wd:Q239 . # Q101=Bernkastel  Q103=Brauneberg Q239=Wiltingen
  ?Etikett wdt:P31 ?Ort . 
  ?Ort rdfs:label ?OrtName .
  FILTER(LANG(?OrtName) = "de")
  ?Etikett wdt:P4 ?Bild 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }}
ORDER BY ASC(?OrtLabel)

Try it!


Klasse der Etiketten (Ortsetikette vs. Lagenetikett) pro Jahrzehnt | Label class (village or vineyard-label) per decade

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT 
  ?Decade
  ?ClassLabel
  (COUNT(?Etikett) AS ?Count)  # Count occurrences of each Class
WHERE {
  ?Etikett wdt:P5/wdt:P6* wd:Q43 . # Match instances of interest
  ?Etikett wdt:P5 ?Class .         # Retrieve Class
  OPTIONAL { 
    ?Etikett wdt:P40 ?PIT . 
    BIND(YEAR(?PIT) AS ?Jahr)      # Extract Year
    BIND(FLOOR(?Jahr / 10) * 10 AS ?Decade)      # Extract Decade
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
GROUP BY ?ClassLabel ?Decade
ORDER BY ASC(?Decade) ?ClassLabel

Try it!


Weingüter | Wineries

Die Weingüter auf einer Karte (nach eigener Geolocation) | The wineries on a map (according to their own geolocation)

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?Weingut ?WeingutLabel ?OrtLabel ?Geokoordinaten
WHERE {
  ?Weingut wdt:P5 wd:Q50 .
  ?Weingut wdt:P51 ?Ort .  
  ?Weingut wdt:P27 ?Geokoordinaten. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Die Weingüter auf einer Karte (mit Geolocation über den Ort) | The wineries on a map (according to their village's geolocation)

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?Weingut ?WeingutLabel ?OrtLabel ?Geokoordinaten
WHERE {
  ?Weingut wdt:P5 wd:Q50 .
  ?Weingut wdt:P51 ?Ort .
  OPTIONAL {?Ort wdt:P27 ?Geokoordinaten.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Die (bisher wenigen) Einzellagen und Weingüter mit Geolocation gemeinsam | The (currently few) vineyards and wineries with their own geolocation

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?Item ?ItemLabel ?typeLabel ?OrtLabel ?Geokoordinaten
WHERE {
  ?Item wdt:P5 ?type . 
  FILTER(?type IN (wd:Q50, wd:Q11))
  ?Item wdt:P18 ?Ort .  
  OPTIONAL { ?Item wdt:P27 ?Geokoordinaten . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Orte | Villages

Alle Orte und Gemeinden auf einer Karte | All villages and towns on a map

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?Ort ?OrtLabel ?Wikidata_ID ?Geolocation
WHERE {
  ?Ort wdt:P5 wd:Q13 .
  OPTIONAL { ?Ort wdt:P12 ?Wikidata_ID . }
  OPTIONAL { ?Ort wdt:P27 ?Geolocation . } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Alle Orte der Mosel mit ihren Lagen (Altlagen und aktuelle Einzellagen) | All villages and towns with their vineyards (historical and current)

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?villageLabel (GROUP_CONCAT(?vineyardLabel; SEPARATOR=", ") AS ?vineyards) ?village
WHERE {
  ?vineyard wdt:P14 ?village.  # P14 = Gemeinde, P18 = Gemarkung
  ?village rdfs:label ?villageLabel. 
  ?vineyard rdfs:label ?vineyardLabel.
  FILTER(LANG(?villageLabel) = "de"). 
  FILTER(LANG(?vineyardLabel) = "de"). 
}
GROUP BY ?village ?villageLabel
ORDER BY ?villageLabel

Try it!


Die Orte der Mosel mit ihren Einzellagen, jeweils separat mit QID | The Mosel villages with their individual vineyards

PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?village ?vineyard ?villageLabel ?vineyardLabel
WHERE {
  ?vineyard wdt:P14 ?village.  # P14 = Gemeinde, P18 = Gemarkung
  ?village rdfs:label ?villageLabel. 
  ?vineyard rdfs:label ?vineyardLabel.
  FILTER(LANG(?villageLabel) = "de"). 
  FILTER(LANG(?vineyardLabel) = "de"). 
}
ORDER BY ?villageLabel

Try it!


Orte mit Timeline-Link | Villages with Timeline-Link

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?OrtLabel ?Geolocation ?Timeline
WHERE {
  ?Ort wdt:P5 wd:Q13 .
  ?Ort wdt:P27 ?Geolocation .
  ?Ort wdt:P89 ?Timeline .  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!


Druckereien | Printers

Druckereien in Rheinland-Pfalz auf einer Karte | Printers in Rhineland-Palatinate on a map

#defaultView:Map
PREFIX wdt:<https://mosel.wikibase.cloud/prop/direct/>
PREFIX wd:<https://mosel.wikibase.cloud/entity/>
SELECT ?KatLabel ?Drucker ?DruckerLabel ?OrtLabel ?Geolocation
WHERE {
  ?Drucker wdt:P5 wd:Q1871 .
  ?Drucker wdt:P5 ?Kat .
  ?Drucker wdt:P51 ?Ort . 
  OPTIONAL { ?Ort wdt:P27 ?Geolocation . }  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!

Retrieved from "https://mosel.wikibase.cloud/w/index.php?title=Project:SPARQL/examples&oldid=19881"